Asmj 6800 syntax

Last revised: 23-Nov-2003

Syntax of 6800 machine instructions

Unless otherwise indicated, all words of all instructions (patterns whose names end in "_instr") must be separated by one or more spaces. We omit those from the syntax expressions for brevity. In other patterns, there are no such omissions; spaces are needed as explicitly specified.

Inherent

Inherent instructions do not need any information to tell where to find the data to operate on; it is implicitly specified as part of the instruction itself. For instance, the "cba" instruction always compares the contents of accumulators A and B; it cannot compare anything else. Syntactically, these are the simplest possible instructions.

	inh_op ::= "aba"|"cba"|"daa"|"sba"|"dex"|"des"|"inx"|"ins"
	          |"clc"|"cli"|"clv"|"sec"|"sei"|"sev"
	          |"tab"|"tba"|"tap"|"tpa"|"txs"|"tsx"
	          |"nop"|"rti"|"rts"|"swi"|"wai"
	          |"clra"|"coma"|"nega"|"deca"|"inca"|"psha"|"pula"
	          |"clrb"|"comb"|"negb"|"decb"|"incb"|"pshb"|"pulb"
	          |"rola"|"rora"|"asla"|"asra"|"lsra"|"tsta"
	          |"rolb"|"rorb"|"aslb"|"asrb"|"lsrb"|"tstb"
	inherent_instr ::= [label] <inh_op> [<comment>]

Operand in memory

Some instructions find one operand in memory, and can do so by any of several addressing modes. For brevity, our syntax diagram allows a few combinations that are actually illegal. For instance, store and jump instructions cannot have immediate operands, and jump instructions also cannot have direct operands.
```
	mem_op ::= "adda"|"adca"|"anda"|"bita"|"cmpa"|"eora"
	          |"ldaa"|"oraa"|"staa"|"suba"|"sbca"
	          |"cpx"|"ldx"|"lds"|"stx"|"sts"|"jsr"|"jmp"
	          |"clr"|"com"|"neg"|"dec"|"inc"|"psh"|"pul"
	          |"rol"|"ror"|"asl"|"asr"|"lsr"|"tst"
	mem_arg ::= <immediate_arg>|<extended_arg>
	           |<direct_arg>|<indexed_arg>
	mem_instr ::= [label] <mem_op> <mem_arg> [<comment>]
```
The syntax of the operand depends on the addressing mode, as follows.
- Immediate
  
  The operand is the byte (or word) in memory immediately following the opcode. The operand argument begins with a pound-sign "#", followed by a numeric expression.
```
	immediate_arg ::= "#" <numeric_expression>
```
- Extended
  
  The operand's address immediately follows the opcode in memory. The operand argument is just a numeric expression.
```
	extended_arg ::= <numeric_expression>
```
- Direct
  
  The byte following the opcode is used as the least significant byte of the operand's address. The most significant byte of the address is implicitly zero. The syntax for direct mode looks just like that for extended; the assembler generates direct-mode instructions automatically when it knows that the operand will be in the first 256 bytes of memory. Note that for this to work, all symbols used in the operand must be defined before the instruction; forward references will force the assembler to use extended addressing instead.
```
	direct_arg ::= <numeric_expression>
```
- Indexed
  
  This mode uses the contents of the index register as the address of the operand. Optionally, you can give a one-byte unsigned constant as an offset to be added to the address of the operand (the index register is not changed by this). Because a letter "x" alone looks to Asmj like an indexed-mode operand, it is not recommended to use that as a symbol name.
```
	indexed_arg ::= [[<numeric_expression>] ","] "x"
```
Branch

Branch instructions always need a single argument: the address to branch to. This can be any numeric expression, although in practice it will usually be just a symbol that was defined as the label of an instruction.
```
	bra_op ::= "bra"|"bcc"|"bcs"|"beq"|"bge"|"bgt"|"bhi"|"ble"
	          |"bls"|"blt"|"bmi"|"bne"|"bvc"|"bvs"|"bpl"|"bsr"
	branch_instr ::= [label] <bra_op> <addr> [<comment>]
```